package com.actualwave{
	import flash.display.DisplayObject;
	import flash.display.DisplayObjectContainer;
	import flash.display.MovieClip;
	import flash.events.Event;
 
	public class FakeParentClip extends MovieClip{
		static public var defaultDefinition:Class = FakeParentClip;
		static public const NAME:String = 'target';
		static public const TARGET_ERROR:String = "Target can not be added twice.";
		protected var _target:DisplayObject;
		public function set target(child:DisplayObject):void{
			if(this._target) throw new Error(TARGET_ERROR);
			this._target = child;
			child.addEventListener(Event.REMOVED_FROM_STAGE, this.removedFromStageHandler);
		}
		protected function removedFromStageHandler(event:Event):void{
			this._target.removeEventListener(Event.REMOVED_FROM_STAGE, this.removedFromStageHandler);
			this._target = null;
		}
		public function get target():DisplayObject{
			return this._target;
		}
		public function removeItemByName(name:String):void{
			delete this[name];
		}
		override public function get root():DisplayObject{
			return this;
		}
	}
}

package com.actualwave{
	import fl.motion.AnimatorBase;
	import fl.motion.AnimatorFactory3D;
	import fl.motion.MotionBase;
 
	import flash.display.DisplayObject;
 
	public class AnimatorFactory3D extends fl.motion.AnimatorFactory3D{
		protected var _parent:FakeParentClip;
		public function AnimatorFactory3D(motion:MotionBase):void{
			super(motion);
			_parent = new FakeParentClip();
		}
		override public function addTarget(target:DisplayObject, repeatCount:int = 0, autoPlay:Boolean = true, startFrame:int = -1, useCurrentFrame:Boolean = false):AnimatorBase{
			if(!target || !target.parent) return null;
			var parent:FakeParentClip = new FakeParentClip.defaultDefinition();
			parent.target = target;
			var animator:AnimatorBase = addTargetInfo(parent, FakeParentClip.NAME, repeatCount, autoPlay, startFrame, useCurrentFrame);
			return animator;
		}
 
	}
}

package{
	import flash.display.DisplayObject;
	import flash.display.DisplayObjectContainer;
 
	import mx.core.Application;
	import mx.core.UIComponent;
	import mx.flash.UIMovieClip;
 
	[DefaultProperty("contentChild")]
	[DefaultProperty("contentChildren")]
	public dynamic class FakeAnimationContainer extends UIMovieClip{
		static public const instance:FakeAnimationContainer = new FakeAnimationContainer();
		protected var _root:DisplayObjectContainer;
		public function FakeAnimationContainer():void{
			super();
			_root = Application.application as DisplayObjectContainer;
		}
		override public function get root():DisplayObject{
			return _root;
		}
		override public function addChild(child:DisplayObject):DisplayObject{
			this[child.name] = child;
			return child;
		}
		override public function addChildAt(child:DisplayObject, index:int):DisplayObject{
			this[child.name] = child;
			return child;
		}
		override public function removeChild(child:DisplayObject):DisplayObject{
			delete this[child.name];
			return child;
		}
		override public function removeChildAt(index:int):DisplayObject{
			throw new Error('Not implemented.');
			return null;
		}
		public function set contentChild(value:UIComponent):void{
			this.addChild(value);
		}
		public function set contentChildren(list:Array):void{
			for each(var p:* in list) this.addChildAt(p, 0);
		}
	}
}

<?xml version="1.0" encoding="utf-8"?>
<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml" layout="absolute" preinitialize="{preinitializeHandler(event)}" xmlns:local="*">
	<mx:Script>
		<![CDATA[
			import fl.motion.AnimatorFactory3D;
			import flash.geom.Vector3D;
			import fl.motion.MotionBase;
			import flash.filters.*;
			import flash.geom.Point;
			private var __motion_Symbol1_6:MotionBase;
    		protected var __animFactory_Symbol1_6:AnimatorFactory3D;
			protected function preinitializeHandler(event:Event):void{
				if(__motion_Symbol1_6 == null) {
				    __motion_Symbol1_6 = new MotionBase();
				    __motion_Symbol1_6.duration = 80;
 
					// ряд значений в виде __motion_Symbol1_6.addPropertyArray(property, [values]);
 
					__animFactory_Symbol1_6 = new AnimatorFactory3D(__motion_Symbol1_6);
				    __animFactory_Symbol1_6.transformationPoint = new Point(97.250000, 63.850000);
				    __animFactory_Symbol1_6.transformationPointZ = 34.850000;
				    /** FakeAnimationContainer использует один глобальный экземпляр и его
				     * можно использовать вместо постоянного создания новых экземпляров.
				     * FakeAnimationContainer.instance.addChild(this.panel);
				     */
				}
			}
		]]>
	</mx:Script>
	<mx:Panel id="panel" name="panel" title="Test flying panel" width="200" height="200" x="200" y="200">
		<mx:Button label="Animate me!" click="{__animFactory_Symbol1_6.addTargetInfo(this.animationParent, 'panel', 0)}"/>
	</mx:Panel>
	<local:FakeAnimationContainer id="animationParent" contentChild="{this.panel}"/>
</mx:Application>